原创 1302的汇编子程序

1302的汇编子程序，是从网上找到的，有点儿灌水嫌疑，呵呵，

;*********************************************************************/
T_CLK Bit P2.5                         ;实时时钟时钟线引脚
T_IO  Bit P2.4                         ;实时时钟数据线引脚
T_RST Bit P2.7                         ;实时时钟复位线引脚

Second data 60h
Minute data 61h
Hour data 62h
Day data 63h
Month data 64h
Week data 65h
Year data 66h

org 0000h
ljmp main
org 0100h

main:
 mov r7, #7
 mov r1, #60h
 mov a, #00h
lop: mov @r1, a
 inc  r1
 djnz r7, lop
 
 lcall Set1302
lcall dly
;lcall dly
;lcall dly 
 ;clr P1.0
 ;mov c, P0.0
 lcall Get1302

 mov r3, 60h
 clr P1.1
 mov c, P0.1
 jnc main
 
dly: mov r6,#0ffh
dly1: mov r5,#0ffh
dly2: mov r4,#10h
dly3: djnz r4,dly3
 djnz r5,dly2
 djnz r6,dly1
 ret 

;**********************************************************
;子程序名：Set1302
;功    能：设置DS1302 初始时间,并启动计时。
;说    明：
;调    用：RTInputByte
;入口参数：初始时间在:Second,Minute,Hour,Day,Month,Week.YearL(地址连续)
;出口参数：无
;影响资源：A B R0 R1 R4 R7
;**********************************************************
Set1302:
          CLR    T_RST
          CLR    T_CLK
          SETB   T_RST
          MOV    B,     #8EH        ;控制寄存器
          LCALL  RTInputByte 
          MOV    B,     #00H        ;写操作前WP="0"
          LCALL  RTInputByte 
          SETB   T_CLK
          CLR    T_RST

          MOV    R0,    #Second;
          MOV    R7,    #7        ;秒 分 时 日 月 星期 年
          MOV    R1,    #80H      ;秒写地址
S13021:   CLR    T_RST
          CLR    T_CLK
          SETB   T_RST
          MOV    B,     R1        ;写秒 分 时 日 月 星期 年 地址
          LCALL  RTInputByte 
          MOV    A,     @R0       ;写秒数据
          MOV    B,     A
          LCALL  RTInputByte 
          INC    R0
          INC    R1
          INC    R1
          SETB   T_CLK
          CLR    T_RST
          DJNZ   R7,    S13021
          CLR    T_RST
          CLR    T_CLK
          SETB   T_RST
          MOV    B,     #8EH        ;控制寄存器
          LCALL  RTInputByte 
          MOV    B,     #80H        ;控制,WP="1",写保护
          LCALL  RTInputByte 
          SETB   T_CLK
          CLR    T_RST
          RET
;**********************************************************
;子程序名：Get1302
;功    能：从DS1302 读时间
;说    明：
;调    用：RTInputByte,RTOutputByte
;入口参数：时间保存在:Second,Minute,Hour,Day,Month,Week.YearL
;出口参数：无
;影响资源：A B R0 R1 R4 R7
;设    计：net                  日    期：2002-03-19
;修    改：                     日    期： 
;**********************************************************
Get1302:     
          MOV    R0,    #Second;
          MOV    R7,    #7
          MOV    R1,    #81H       ;秒地址
G13021:   CLR    T_RST
          CLR    T_CLK
          SETB   T_RST
          MOV    B,     R1        ;秒 分 时 日 月 星期 年 地址
          LCALL  RTInputByte 
          LCALL  RTOutputByte
          MOV    @R0,   A         ;秒
          INC    R0
          INC    R1
          INC    R1
          SETB   T_CLK
          CLR    T_RST
          DJNZ   R7,    G13021
          RET
;**********************************************************
;功    能：写1302一字节  （内部子程序）
;**********************************************************
RTInputByte: 
          MOV    R4,    #8
Inbit1:   MOV    A,     B
   RRC    A
          MOV    B,     A
   nop
   nop
   nop 
          MOV    T_IO,  C
          SETB   T_CLK
   nop
   nop
          CLR    T_CLK
          DJNZ   R4,   Inbit1
          RET
;**********************************************************
;功    能：读1302一字节  （内部子程序）
;**********************************************************
RTOutputByte:
          MOV    R4,    #8
Outbit1:  MOV    C,     T_IO
          RRC    A
          SETB   T_CLK
          nop
   CLR    T_CLK
          nop
   DJNZ   R4,    Outbit1
          nop
   RET
;***************************************************
end