原创 u-boot的arm720t lds链接文件介绍

该文件的地址为：u-boot\arch\arm\cpu\arm720t，下面详细介绍该文件：

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")

/* 指定输出可执行文件是elf格式，32位ARM指令，小端模式 */

OUTPUT_ARCH(arm)      /* 指定输出可执行文件的平台是ARM     */ 

ENTRY(_start)            /* 指定输出可执行文件的起始代码段为 _start */ 

SECTIONS

{

       . = 0x00000000;     /* 指定可执行image文件的全局入口点，通常这个地址都放在ROM（flash）0x0位置。   必须使编译器知道这个地址，通常是修改此处来完成 */ 

       . = ALIGN(4);                   /* 代码以4字节对齐  */

       .text :

       {

              arch/arm/cpu/arm720t/start.o(.text) /* start.S代码放在最开始处*/

              *(.text)                          /* 其他代码部分 */  

       }

       . = ALIGN(4);                          /* rodata 以4字节对齐*/ 

       .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) } 

                                             /* 指定只读数据段   */ 

       . = ALIGN(4);                        /* .data 以4字节对齐  */

       .data : { *(.data) }                /* 指定读，写数据段    */

       . = ALIGN(4);                       /* .got 以4字节对齐   */

       .got : { *(.got) }                 /* 指定got段，got段是uboot */

                                         /* 自定义的一个段，非标准段 */

       . = .;                           

       __u_boot_cmd_start = .;   /* 指定__u_boot_cmd_start 段起始位置*/

       .u_boot_cmd : { *(.u_boot_cmd) } /* 指定u_boot_cmd 段，uboot*/

/*把所有的uboot命令放在该段     */

       __u_boot_cmd_end = .;     /* 指定__u_boot_cmd_end 结束位置 */

       . = ALIGN(4);

       __bss_start = .;                 /* 指定bss段的开始位置     */

       .bss (NOLOAD) : { *(.bss) . = ALIGN(4); } /* 指定bss段    */ 

       _end = .;                        /* 指定bss段的结束位置     */

}

问题：如何通过lds文件计算出代码的大小？

__bss_start段之前的所有代码都为有效代码，包括.text（真正的代码）、.rodata（只读数据段）、.data（可读写数据段）等。bss段是未初始化数据区，因为这些变量不需要初始化，不需要在代码中保存初始化值，所以不占用代码空间。

因此，代码的大小可以这样算出来：__bss_start的地址 减去 _start的地址。

示例：ARM720t的start.s

       ldr   r2, _armboot_start

       ldr   r3, _bss_start

       sub  r2, r3, r2        /* r2 <- size of armboot     */

上面这段汇编是计算C代码（_armboot_start为C程序的入口，从_armboot_start段开始都是C代码）的大小，其值保存在如r2寄存器中。