原创 单片机学习（续）

逻辑与指令<?xml:namespace prefix = o ns = "urn:schemas-microsoft-com:office:office" />

ANL              A,Rn        ;A与Rn中的值按位'与'，结果送入A中

ANL              A,direct ;A与direct中的值按位'与'，结果送入A中

ANL              A,@Ri ;A与间址寻址单元@Ri中的值按位'与'，结果送入A中

ANL              A,#data ;A与立即数data按位'与'，结果送入A中

ANL              direct,A ;direct中值与A中的值按位'与'，结果送入direct中

ANL              direct,#data ;direct中的值与立即数data按位'与'，结果送入direct中。

这几条指令的关键是知道什么是逻辑与。这里的逻辑与是指按位与

例：71H和56H相与则将两数写成二进制形式：

（71H） 01110001

（56H） 00100110

结果 00100000 即20H，从上面的式子可以看出，两个参与运算的值只要其中有一个位上是0，则这位的结果就是0，两个同是1，结果才是1。

理解了逻辑与的运算规则，结果自然就出来了。看每条指令后面的注释

下面再举一些例子来看。

MOV              A，#45H ;(A)=45H

MOV              R1，#25H ;(R1)=25H

MOV              25H，#79H ;(25H)=79H

ANL              A，@R1 ;45H与79H按位与，结果送入A中为 41H （A）=41H

ANL              25H,#15H ;25H中的值（79H）与15H相与结果为（25H）=11H）

ANL              25H,A ;25H中的值（11H）与A中的值（41H)相与，结果为(25H)=11H

在知道了逻辑与指令的功能后，逻辑或和逻辑异或的功能就很简单了。逻辑或是按位“或”，即有“1”为1，全“0”为0。例：

10011000

或 01100001

结果 11111001

而异或则是按位“异或”，相同为“0”，相异为“1”。例：

10011000

异或 01100001

结果 11111001

而所有的或指令，就是将与指仿中的ANL 换成ORL，而异或指令则是将ANL       换成XRL。即

或指令：

ORL              A,Rn        ;A和Rn中的值按位'或'，结果送入A中

ORL              A,direct ;A和与间址寻址单元@Ri中的值按位'或'，结果送入A中

ORL              A,#data ;A和立direct中的值按位'或'，结果送入A中

ORL              A,@Ri ;A和即数data按位'或'，结果送入A中

ORL              direct,A ;direct中值和A中的值按位'或'，结果送入direct中

ORL              direct,#data ;direct中的值和立即数data按位'或'，结果送入direct中。

异或指令：

XRL              A,Rn        ;A和Rn中的值按位'异或'，结果送入A中

XRL              A,direct ;A和direct中的值按位'异或'，结果送入A中

XRL              A,@Ri ;A和间址寻址单元@Ri中的值按位'异或'，结果送入A中

XRL              A,#data ;A和立即数data按位'异或'，结果送入A中

XRL              direct,A ;direct中值和A中的值按位'异或'，结果送入direct中

XRL              direct,#data ;direct中的值和立即数data按位'异或'，结果送入direct中。

练习：

MOV              A，#24H

MOV              R0，#37H

ORL                     A，R0

XRL                     A，#29H

MOV              35H，#10H

ORL                     35H，#29H

MOV              R0，#35H

ANL              A，@R0

四、控制转移类指令

1. 
   
2. 
   

   短转移类指令

AJMP       addr11

2. 
   
3. 
   

   长转移类指令

LJMP       addr16

3. 
   
4. 
   

   相对转移指令

SJMP       rel

上面的三条指令，如果要仔细分析的话，区别较大，但初学时，可不理会这么多，统统理解成：JMP         标号，也就是跳转到一个标号处。事实上，LJMP              标号，在前面的例程中我们已接触过，并且也知道如何来使用了。而AJMP和SJMP也是一样。那么他们的区别何在呢？在于跳转的范围不一样。好比跳远，LJMP一下就能跳64K这么远（当然近了更没关系了）。而AJMP       最多只能跳2K距离，而SJMP则最多只能跳256这么远。原则上，所有用SJMP或AJMP的地方都可以用LJMP来替代。因此在初学时，需要跳转时可以全用LJMP，除了一个场合。什么场合呢？先了解一下AJMP，AJMP是一条双字节指令，也就说这条指令本身占用存储器（ROM）的两个单元。而LJMP则是三字节指令，即这条指令占用存储器（ROM）的三个单元。下面是第四条跳转指令。

4. 
   
5. 
   

   间接转移指令

JMP         @A+DPTR

这条指令的用途也是跳转，转到什么地方去呢？这可不能由标号简单地决定了。让我们从一个实际的例子入手吧。

MOV    DPTR，#TAB       ;将TAB所代表的地址送入DPTR

MOV    A，R0                  ;从R0中取数（详见下面说明）

MOV    B，#2                        

MUL    A，B           ;A中的值乘2（详见下面的说明）

JMP    A，@A+DPTR      ;跳转

TAB:      AJMP     S1          ;跳转表格

    AJMP     S2

       AJMP     S3

              .

              .

              .

　　应用背景介绍：在单片机开发中，经常要用到键盘，见上面的9个按键的键盘。我们的要求是：当按下功能键A………..G时去完成不同的功能。这用程序设计的语言来表达的话，就是：按下不同的键去执行不同的程序段，以完成不同的功能。怎么样来实现呢？

　　看图2，前面的程序读入的是按键的值，如按下'A'键后获得的键值是0，按下'B'键后获得的值是'1'等等，然后根据不同的值进行跳转，如键值为0就转到S1执行，为1就转到S2执行。。。。如何来实现这一功能呢？

　　先从程序的下面看起，是若干个AJMP语句，这若干个AJMP语句最后在存储器中是这样存放的（见图3），也就是每个AJMP语句都占用了两个存储器的空间，并且是连续存放的。而AJMP    S1存放的地址是TAB，到底TAB等于多少，我们不需要知道，把它留给汇编程序来算好了。

　　下面我们来看这段程序的执行过程：第一句MOV DPTR，#TAB执行完了之后，DPTR中的值就是TAB，第二句是MOV A，R0，我们假设R0是由按键处理程序获得的键值，比如按下A键，R0中的值是0，按下B键，R0中的值是1，以此类推，现在我们假设按下的是B键，则执行完第二条指令后，A中的值就是1。并且按我们的分析，按下B后应当执行S2这段程序，让我们来看一看是否是这样呢？第三条、第四条指令是将A中的值乘2，即执行完第4条指令后A中的值是2。下面就执行JMP @A+DPTR了，现在DPTR中的值是TAB，而A+DPTR后就是TAB+2，因此，执行此句程序后，将会跳到TAB+2这个地址继续执行。看一看在TAB+2这个地址里面放的是什么？就是AJMP       S2这条指令。因此，马上又执行AJMP        S2指令，程序将跳到S2处往下执行，这与我们的要求相符合。

请大家自行分析按下键“A”、“C”、“D”……之后的情况。

　　这样我们用JMP   @A+DPTR就实现了按下一键跳到相应的程序段去执行的这样一个要求。再问大家一个问题，为什么取得键值后要乘2？如果例程下面的所有指令换成LJMP，即：

LJMP     S1,LJMP        S2……这段程序还能正确地执行吗？如果不能，应该怎么改？

单片机第十三课

条件转移指令：

条件转移指令是指在满足一定条件时进行相对转移。

1. 
   
2. 
   

   判A内容是否为0转移指令

   
   
   
   

   JZ rel

   
   

   JNZ rel

   
   

   第一指令的功能是：如果(A)=0，则转移，否则顺序执行（执行本指令的下一条指令）。转移到什么地方去呢？如果按照传统的方法，就要算偏移量，很麻烦，好在现在我们可以借助于机器汇编了。因此这第指令我们可以这样理解：JZ 标号。即转移到标号处。下面举一例说明：

   
   

   MOV A,R0

   
   

   JZ L1

   
   

   MOV R1,#00H

   
   

   AJMP L2

   
   

   L1: MOV R1,#0FFH

   
   

   L2: SJMP L2

   
   

   END

   
   

   在执行上面这段程序前如果R0中的值是0的话，就转移到L1执行，因此最终的执行结果是R1中的值为0FFH。而如果R0中的值不等于0，则顺序执行，也就是执行 MOV R1，#00H指令。最终的执行结果是R1中的值等于0。

   
   

   第一条指令的功能清楚了，第二条当然就好理解了，如果A中的值不等于0，就转移。把上面的那个例子中的JZ改成JNZ试试吧，看看程序执行的结果是什么?

   
   

   　

   
   
   
   
3. 
   

   比较转移指令

CJNE A,#data,rel

CJNE A,direct,rel

CJNE Rn,#data,rel

CJNE @Ri,#data,rel

第一条指令的功能是将A中的值和立即数data比较，如果两者相等，就顺序执行（执行本指令的下一条指令），如果不相等，就转移，同样地，我们可以将rel理解成标号，即：CJNE A，#data,标号。这样利用这条指令，我们就可以判断两数是否相等，这在很多场合是非常有用的。但有时还想得知两数比较之后哪个大，哪个小，本条指令也具有这样的功能，如果两数不相等，则CPU还会反映出哪个数大，哪个数小，这是用CY（进位位）来实现的。如果前面的数（A中的）大，则CY=0，否则CY=1，因此在程序转移后再次利用CY就可判断出A中的数比data大还是小了。

例：

MOV A,R0

CJNE A,#10H,L1

MOV R1,#0FFH

AJMP L3

L1: JC L2

MOV R1,#0AAH

AJMP L3

L2: MOV R1,#0FFH

L3: SJMP L3

上面的程序中有一条指令我们还没学过，即JC，这条指令的原型是JC rel,作用和上面的JZ类似，但是它是判CY是0，还是1进行转移，如果CY=1，则转移到JC后面的标号处执行，如果CY=0则顺序执行（执行它的下面一条指令）。

分析一下上面的程序，如果（A）=10H，则顺序执行，即R1=0。如果（A）不等于10H，则转到L1处继续执行，在L1处，再次进行判断，如果（A）>10H，则CY=1，将顺序执行，即执行MOV R1，#0AAH指令，而如果（A）<10H，则将转移到L2处指行，即执行MOV R1，#0FFH指令。因此最终结果是：本程序执行前，如果（R0）=10H，则（R1）=00H，如果（R0）>10H，则（R1）=0AAH，如果（R0）<10H，则（R1）=0FFH。

弄懂了这条指令，其它的几条就类似了，第二条是把A当中的值和直接地址中的值比较，第三条则是将直接地址中的值和立即数比较，第四条是将间址寻址得到的数和立即数比较，这里就不详谈了，下面给出几个相应的例子。

CJNE A,10H ;把A中的值和10H中的值比较（注意和上题的区别）

CJNE 10H，#35H ;把10H中的值和35H中的值比较

CJNE @R0,#35H ;把R0中的值作为地址，从此地址中取数并和35H比较

循环转移指令

DJNZ Rn,rel

DJNZ direct,rel

第一条指令在前面的例子中有详细的分析，这里就不多谈了。第二条指令，只是将Rn改成直接地址，其它一样，也不多说了，给一个例子。

DJNZ 10H，LOOP

3．调用与返回指令

（1）主程序与子程序 在前面的灯的实验中，我们已用到过了子程序，只是我们并没有明确地介绍。子程序是干什么用的，为什么要用子程序技术呢？举个例子，我们数据老师布置了10道算术题，经过观察，每一道题中都包含一个（3*5+2）*3的运算，我们可以有两种选择，第一种，每做一道题，都把这个算式算一遍，第二种选择，我们可以先把这个结果算出来，也就是51，放在一边，然后要用到这个算式时就将51代进去。这两种方法哪种更好呢？不必多言。设计程序时也是这样，有时一个功能会在程序的不同地方反复使用，我们就可以把这个功能做成一段程序，每次需要用到这个功能时就“调用”一下。

（2）调用及回过程：主程序调用了子程序，子程序执行完之后必须再回到主程序继续执行，不能“一去不回头”，那么回到什么地方呢？是回到调用子程序的下面一条指令继续执行（当然啦，要是还回到这条指令，不又要再调用子程序了吗？那可就没完没了了……）。参考图1

图1

调用指令

LCALL addr16 ;长调用指令

ACALL addr11 ;短调用指令

上面两条指令都是在主程序中调用子程序，两者有一定的区别，但在初学时，可以不加以区分，而且可以用LCALL 标号，ACALL 标号，来理解，即调用子程序。

（5）返回指令 则说了，子程序执行完后必须回到主程序，如何返回呢？只要执行一条返回指令就可以了，即执行

ret

指令

4．空操作指令

nop

空操作，就是什么事也不干，停一个周期，一般用作短时间的延时。

单片机第十七课

位及位操作指令

通过前面那些流水灯的例子，我们已经习惯了“位”一位就是一盏灯的亮和灭，而我们学的指令却全都是用“字节”来介绍的：字节的移动、加法、减法、逻辑运算、移位等等。用字节来处理一些数学问题，比如说：控制冰箱的温度、电视的音量等等很直观，可以直接用数值来表在。可是如果用它来控制一些开关的打开和合上，灯的亮和灭，就有些不直接了，记得我们上次课上的流水灯的例子吗？我们知道送往P1口的数值后并不能马上知道哪个灯亮和来灭，而是要化成二进制才知道。工业中有很多场合需要处理这类开关输出，继电器吸合，用字节来处理就显示有些麻烦，所以在8031单片机中特意引入一个位处理机制。

位寻址区

在8031中，有一部份RAM和一部份SFR是具有位寻址功能的，也就是说这些RAM的每一个位都有自已的地址，可以直接用这个地址来对此进行操作。

图1

内部RAM的20H-2FH这16个字节，就是8031的位寻址区。看图1。可见这里面的每一个RAM中的每个位我们都可能直接用位地址来找到它们，而不必用字节地址，然后再用逻辑指令的方式。

可以位寻址的特殊功能寄存器

8031中有一些SFR是可以进行位寻址的，这些SFR的特点是其字节地址均可被8整除，如A累加器，B寄存器、PSW、IP（中断优先级控制寄存器）、IE（中断允许控制寄存器）、SCON（串行口控制寄存器）、TCON（定时器/计数器控制寄存器）、P0-P3（I/O端口锁存器）。以上的一些SFR我们还不熟，等我们讲解相关内容时再作详细解释。

位操作指令

MCS-51单片机的硬件结构中，有一个位处理器（又称布尔处理器），它有一套位变量处理的指令集。在进行位处理时，CY（就是我们前面讲的进位位）称“位累加器”。有自已的位RAM，也就是我们刚讲的内部RAM的20H-2FH这16个字节单元即128个位单元，还有自已的位I/O空间（即P0.0…..P0.7,P1.0…….P1.7,P2.0……..P2.7,P3.0……..P3.7）。当然在物理实体上它们与原来的以字节寻址用的RAM，及端口是完全相同的，或者说这些RAM及端口都可以有两种用法。

位传送指令

MOV C，BIT

MOV BIT，C

这组指令的功能是实现位累加器（CY）和其它位地址之间的数据传递。

例：MOV P1.0,CY ;将CY中的状态送到P1.0引脚上去（如果是做算术运算，我们就可以通过观察知道现在CY是多少啦）。

MOV P1.0,CY ;将P1.0的状态送给CY。

位修正指令

位清0指令

CLR C ;使CY=0

CLR bit ;使指令的位地址等于0。例：CLR P1.0 ;即使P1.0变为0

位置1指令

SETB C ;使CY=1

SETB bit ;使指定的位地址等于1。例：SETB P1.0 ;使P.0变为1

位取反指令

CPL C ;使CY等于原来的相反的值，由1变为0，由0变为1。

CPL bit ;使指定的位的值等于原来相反的值，由0变为1，由1变为0。

例：CPL P1.0

以我们做过的实验为例，如果原来灯是亮的，则执行本指令后灯灭，反之原来灯是灭的，执行本指令后灯亮。

位逻辑运算指令

位与指令

ANL C,bit ;CY与指定的位地址的值相与，结果送回CY

ANL C,/bit ;先将指定的位地址中的值取出后取反，再和CY相与，结果送回CY，但注意，指定的位地址中的值本身并不发生变化。

例：ANL C,/P1.0

设执行本指令前，CY=1，P1.0等于1（灯灭），则执行完本指令后CY=0，而P1.0也是等于1。

可用下列程序验证：

ORG 0000H

AJMP START

ORG 30H

START： MOV SP，#5FH

MOV P1，#0FFH

SETB C

ANL C，/P1.0

MOV P1.1,C ;将做完的结果送P1.1,结果应当是P1.1上的灯亮，而P1.0上的灯还是不亮。

位或指令

ORL C,bit

ORL C,/bit

这个的功能大家自行分析吧，然后对照上面的例程，编一个验证程序，看看你相得对吗？

位条件转移指令

判CY转移指令

JC rel

JNC rel

第一条指令的功能是如果CY等于1就转移，如果不等于1就顺序执行。那么转移到什么地方去呢？我们可以这样理解：JC 标号，如果等于1就转到标号处执行。这条指令我们在上节课中已讲到，不再重复。

第二条指令则和第一条指令相反，即如果CY=0就转移，不等于0就顺序执行，当然，我们也同样理解： JNC 标号

判位变量转移指令

JB bit,rel

JNB bit,rel

第一条指令是如果指定的bit位中的值是1，则转移，否则顺序执行。同样，我们可以这样理解这条指令：JB bit,标号

第二条指令请大家先自行分析

下面我们举个例子说明：

ORG 0000H

LJMP START

ORG 30H

START：MOV SP，#5FH

MOV P1，#0FFH

MOV P3，#0FFH

L1: JNB P3.2,L2 ;P3.2上接有一只按键，它按下时，P3.2=0

JNB P3.3,L3 ;P3.3上接有一只按键，它按下时，P3.3=0

LJM P L1

L2: MOV P1,#00H

LJMP L1

L3: MOV P1,#0FFH

LJMP L1

END

把上面的例子写入片子，看看有什么现象………

.

.

按下接在P3.2上的按键，P1口的灯全亮了，松开或再按，灯并不熄灭，然后按下接在P3.3上的按键，灯就全灭了。这像什么？这不就是工业现场经常用到的“启动”、“停止”的功能吗？

怎么做到的呢？一开始，将0FFH送入P3口，这样，P3的所有引线都处于高电平，然后执行L1，如果P3.2是高电平（键没有按下），则顺序执行JNB P3.3,L3语句，同样，如果P3.3是高电平（键没有按下），则顺序执行LJMP L1语句。这样就不停地检测P3.2、P3.3，如果有一次P3.2上的按键按下去了，则转移到L2，执行MOV P1，#00H，使灯全亮，然后又转去L1，再次循环，直到检测到P3.3为0，则转L3，执行MOV P1，#0FFH，例灯全灭，再转去L1，如此循环不已。

大家能否稍加改动，将本程序用JB指令改写？

计数器与定时器

一、计数概念的引入

从选票的统计谈起：画“正”。这就是计数，生活中计数的例子处处可见。例：录音机上的计数器、家里面用的电度表、汽车上的里程表等等，再举一个工业生产中的例子，线缆行业在电线生产出来之后要计米，也就是测量长度，怎么测法呢？用尺量？不现实，太长不说，要一边做一边量呢，怎么办呢？行业中有很巧妙的方法，用一个周长是1米的轮子，将电缆绕在上面一周，由线带轮转，这样轮转一周不就是线长1米嘛，所以只要记下轮转了多少圈，就可以知道走过的线有多长了。

二、计数器的容量

从一个生活中的例子看起：一个水盆在水龙头下，水龙没关紧，水一滴滴地滴入盆中。水滴不断落下，盆的容量是有限的，过一段时间之后，水就会逐渐变满。录音机上的计数器最多只计到999….那么单片机中的计数器有多大的容量呢？8031单片机中有两个计数器，分别称之为T0和T1，这两个计数器分别是由两个8位的RAM单元组成的，即每个计数器都是16位的计数器，最大的计数量是65536。

三、定时

8031中的计数器除了可以作为计数之用外，还可以用作时钟，时钟的用途当然很大，如打铃器，电视机定时关机，空调定时开关等等，那么计数器是如何作为定时器来用的呢？

一个闹钟，我将它定时在1个小时后闹响，换言之，也可以说是秒针走了（3600）次，所以时间就转化为秒针走的次数的，也就是计数的次数了，可见，计数的次数和时间之间的确十分相关。那么它们的关系是什么呢？那就是秒针每一次走动的时间正好是1秒。

图1

结论：只要计数脉冲的间隔相等，则计数值就代表了时间的流逝。

由此，单片机中的定时器和计数器是一个东西，只不过计数器是记录的外界发生的事情，而定时器则是由单片机提供一个非常稳定的计数源。

那么提供组定时器的是计数源是什么呢？看图1，原来就是由单片机的晶振经过12分频后获得的一个脉冲源。晶振的频率当然很准，所以这个计数脉冲的时间间隔也很准。问题：一个12M的晶振，它提供给计数器的脉冲时间间隔是多少呢？当然这很容易，就是12M/12等于1M，也就是1个微秒。

结论：计数脉冲的间隔与晶振有关，12M的晶振，计数脉冲的间隔是1微秒。

四、溢出

让我们再来看水滴的例子，当水不断落下，盆中的水不断变满，最终有一滴水使得盆中的水满了。这时如果再有一滴水落下，就会发生什么现象？水会漫出来，用个术语来讲就是“溢出”。

水溢出是流到地上，而计数器溢出后将使得TF0变为“1”。至于TF0是什么我们稍后再谈。一旦TF0由0变成1，就是产生了变化，产生了变化就会引发事件，就象定时的时间一到，闹钟就会响一样。至于会引发什么事件，我们下次课再介绍，现在我们来研究另一个问题：要有多少个计数脉冲才会使TF0由0变为1。

五、任意定时及计数的方法

刚才已研究过，计数器的容量是16位，也就是最大的计数值到65536，因此计数计到65536就会产生溢出。这个没有问题，问题是我们现实生活中，经常会有少于65536个计数值的要求，如包装线上，一打为12瓶，一瓶药片为100粒，怎么样来满足这个要求呢？

……

提示：如果是一个空的盆要1万滴水滴进去才会满，我在开始滴水之前就先放入一勺水，还需要10000滴嘛？

对了，我们采用预置数的方法，我要计100，那我就先放进65436，再来100个脉冲，不就到了65536了吗。

定时也是如此，每个脉冲是1微秒，则计满65536个脉冲需时65.536毫秒，但现在我只要10毫秒就可以了，怎么办？

……

10个毫秒为10000个微秒，所以，只要在计数器里面放进55536就可以了。

说明：本课部份图请打本单片机书，都有，抱歉，不及画。

定时/计数器的方式控制字

从上一节我们已经得知，单片机中的定时/计数器都可以有多种用途，那么我怎样才能让它们工作于我所需要的用途呢？这就要通过定时/计数器的方式控制字来设置。

在单片机中有两个特殊功能寄存器与定时/计数有关，这就是TMOD和TCON。顺便说一下，TMOD和TCON是名称，我们在写程序时就可以直接用这个名称来指定它们，当然也可以直接用它们的地址89H和88H来指定它们（其实用名称也就是直接用地址，汇编软件帮你翻译一下而已）。

从图1中我们可以看出，TMOD被分成两部份，每部份4位。分别用于控制T1和T0，至于这里面是什么意思，我们下面介绍。

从图2中我们可以看出，TCON也被分成两部份，高4位用于定时/计数器，低4位则用于中断（我们暂不管）。而TF1（0）我们上节课已提到了，当计数溢出后TF1（0）就由0变为1。原来TF1（0）在这儿！那么TR0、TR1又是什么呢？看上节课的图。

计数脉冲要进入计数器还真不容易，有层层关要通过，最起码，就是TR0（1）要为1，开关才能合上，脉冲才能过来。因此，TR0（1）称之为运行控制位，可用指令SETB来置位以启动计数器/定时器运行，用指令CLR来关闭定时/计数器的工作，一切尽在自已的掌握中。

定时/计数器的四种工作方式

工作方式0

定时器/计数器的工作方式0称之为13位定时/计数方式。它由TL（1/0）的低5位和TH（0/1）的8位构成13位的计数器，此时TL（1/0）的高3位未用。

我们用这个图来讨论几个问题：

M1M0：定时/计数器一共有四种工作方式，就是用M1M0来控制的，2位正好是四种组合。

C/T：前面我们说过，定时/计数器即可作定时用也可用计数用，到底作什么用，由我们根据需要自行决定，也说是决定权在我们&#0;&#0;编程者。如果C/T为0就是用作定时器（开关往上打），如果C/T为1就是用作计数器（开关往下打）。顺便提一下：一个定时/计数器同一时刻要么作定时用，要么作计数用，不能同时用的，这是个极普通的常识，几乎没有教材会提这一点，但很多初学者却会有此困惑。

GATE：看图，当我们选择了定时或计数工作方式后，定时/计数脉冲却不一定能到达计数器端，中间还有一个开关，显然这个开关不合上，计数脉冲就没法过去，那么开关什么时候过去呢？有两种情况

GATE=0，分析一下逻辑，GATE非后是1，进入或门，或门总是输出1，和或门的另一个输入端INT1无关，在这种情况下，开关的打开、合上只取决于TR1，只要TR1是1，开关就合上，计数脉冲得以畅通无阻，而如果TR1等于0则开关打开，计数脉冲无法通过，因此定时/计数是否工作，只取决于TR1。

GATE=1，在此种情况下，计数脉冲通路上的开关不仅要由TR1来控制，而且还要受到INT1引脚的控制，只有TR1为1，且INT1引脚也是高电平，开关才合上，计数脉冲才得以通过。这个特性可以用来测量一个信号的高电平的宽度，想想看，怎么测？

为什 么在这种模式下只用13位呢？干吗不用16位，这是为了和51机的前辈48系列兼容而设的一种工作式，如果你觉得用得不顺手，那就干脆用第二种工作方式。

工作方式1

工作方式1是16位的定时/计数方式，将M1M0设为01即可，其它特性与工作方式0相同。

工作方式2

在介绍这种式方式之前先让我们思考一个问题：上一次课我们提到过任意计数及任意定时的问题，比如我要计1000个数，可是16位的计数器要计到65536才满，怎么办呢？我们讨论后得出的办法是用预置数，先在计数器里放上64536，再来1000个脉冲，不就行了吗？是的，但是计满了之后我们又该怎么办呢？要知道，计数总是不断重复的，流水线上计满后马上又要开始下一次计数，下一次的计数还是1000吗？当计满并溢出后，计数器里面的值变成了0（为什么，可以参考前面课程的说明），因此下一次将要计满65536后才会溢出，这可不符合要求，怎么办？当然办法很简单，就是每次一溢出时执行一段程序（这通常是需要的，要不然要溢出干吗？）可以在这段程序中做把预置数64536送入计数器中的事情。所以采用工作方式0或1都要在溢出后做一个重置预置数的工作，做工作当然就得要时间，一般来说这点时间不算什么，可是有一些场合我们还是要计较的，所以就有了第三种工作方式&#0;&#0;自动再装入预置数的工作方式。

既然要自动得新装入预置数，那么预置数就得放在一个地方，要不然装什么呢？那么预置数放在什么地方呢？它放在T（0/1）的高8位，那么这样高8位不就不能参与计数了吗？是的，在工作方式2，只有低8位参与计数，而高8位不参与计数，用作预置数的存放，这样计数范围就小多了，当然做任可事总有代价的，关键是看值不值，如果我根本不需要计那么多数，那么就可以用这种方式。看图4，每当计数溢出，就会打开T（0/1）的高、低8位之间的开关，计预置数进入低8位。这是由硬件自动完成的，不需要由人工干预。

通常这种式作方式用于波特率发生器（我们将在串行接口中讲解），用于这种用途时，定时器就是为了提供一个时间基准。计数溢出后不需要做事情，要做的仅仅只有一件，就是重新装入预置数，再开始计数，而且中间不要任何延迟，可见这个任务用工作方式2来完成是最妙不过了。

工作方式3

这种式作方式之下，定时/计数器0被拆成2个独立的定时/计数器来用。其中，TL0可以构成8位的定时器或计数器的工作方式，而TH0则只能作为定时器来用。我们知道作定时、计数器来用，需要控制，计满后溢出需要有溢出标记，T0被分成两个来用，那就要两套控制及、溢出标记了，从何而来呢？TL0还是用原来的T0的标记，而TH0则借用T1的标记。如此T1不是无标记、控制可用了吗？是的。

一般情况处，只有在T1以工作方式2运行（当波特率发生器用）时，才让T0工作于方式3的。

定时器/计数器的定时/计数范围

工作方式0：13位定时/计数方式，因此，最多可以计到2的13次方，也就是8192次。

工作方式1：16位定时/计数方式，因此，最多可以计到2的16次方，也就是65536次。

工作方式2和工作方式3，都是8位的定时/计数方式，因此，最多可以计到2的8次方，也说是256次。

预置值计算：用最大计数量减去需要的计数次数即可。

例：流水线上一个包装是12盒，要求每到12盒就产生一个动作，用单片机的工作方式0来控制，应当预置多大的值呢？对了，就是8192-12=8180。

以上是计数，明白了这个道理，定时也是一样。这在前面的课程已提到，我们不再重复，请参考前面的例子。

单片机第二十课：中断系统

有关中断的概念

什么是中断，我们从一个生活中的例子引入。你正在家中看书，突然电话铃响了，你放下书本，去接电话，和来电话的人交谈，然后放下电话，回来继续看你的书。这就是生活中的“中断”的现象，就是正常的工作过程被外部的事件打断了。

仔细研究一下生活中的中断，对于我们学习单片机的中断也很有好处。第一、什么可经引起中断，生活中很多事件可以引起中断：有人按了门铃了，电话铃响了，你的闹钟闹响了，你烧的水开了….等等诸如此类的事件，我们把可以引起中断的称之为中断源，单片机中也有一些可以引起中断的事件，8031中一共有5个：两个外部中断，两个计数/定时器中断，一个串行口中断。

第二、中断的嵌套与优先级处理：设想一下，我们正在看书，电话铃响了，同时又有人按了门铃，你该先做那样呢？如果你正是在等一个很重要的电话，你一般不会去理会门铃的，而反之，你正在等一个重要的客人，则可能就不会去理会电话了。如果不是这两者（即不等电话，也不是等人上门），你可能会按你通常的习惯去处理。总之这里存在一个优先级的问题，单片机中也是如此，也有优先级的问题。优先级的问题不仅仅发生在两个中断同时产生的情况，也发生在一个中断已产生，又有一个中断产生的情况，比如你正接电话，有人按门铃的情况，或你正开门与人交谈，又有电话响了情况。考虑一下我们会怎么办吧。

第三、中断的响应过程：当有事件产生，进入中断之前我们必须先记住现在看书的第几页了，或拿一个书签放在当前页的位置，然后去处理不同的事情（因为处理完了，我们还要回来继续看书）：电话铃响我们要到放电话的地方去，门铃响我们要到门那边去，也说是不同的中断，我们要在不同的地点处理，而这个地点通常还是固定的。计算机中也是采用的这种方法，五个中断源，每个中断产生后都到一个固定的地方去找处理这个中断的程序，当然在去之前首先要保存下面将执行的指令的地址，以便处理完中断后回到原来的地方继续往下执行程序。具体地说，中断响应可以分为以下几个步骤：1、保护断点，即保存下一将要执行的指令的地址，就是把这个地址送入堆栈。2、寻找中断入口，根据5个不同的中断源所产生的中断，查找5个不同的入口地址。以上工作是由计算机自动完成的，与编程者无关。在这5个入口地址处存放有中断处理程序（这是程序编写时放在那儿的，如果没把中断程序放在那儿，就错了，中断程序就不能被执行到）。3、执行中断处理程序。4、中断返回：执行完中断指令后，就从中断处返回到主程序，继续执行。

究竟单片机是怎么样找到中断程序所在位置，又怎么返回的呢？我们稍后再谈。

MCS-51中断系统的结构：

如图（抱歉，本图请找本51书看一下）所示，由与中断有关的特殊功能寄存器、中断入口、顺序查询逻辑电路等组成，包括5个中断请求源，4个用于中断控制的寄存器IE、IP、ECON和SCON来控制中断 类弄、中断的开、关和各种中断源的优先级确定。

中断请求源：

（1）外部中断请求源：即外中断0和1，经由外部引脚引入的，在单片机上有两个引脚，名称为INT0、INT1，也就是P3.2、P3.3这两个引脚。在内部的TCON中有四位是与外中断有关的。

IT0：INT0触发方式控制位，可由软件进和置位和复位，IT0=0，INT0为低电平触发方式，IT0=1，INT0为负跳变触发方式。这两种方式的差异将在以后再谈。

IE0：INT0中断请求标志位。当有外部的中断请求时，这位就会置1（这由硬件来完成），在CPU响应中断后，由硬件将IE0清0。

IT1、IE1的用途和IT0、IE0相同。

（2）内部中断请求源

TF0：定时器T0的溢出中断标记，当T0计数产生溢出时，由硬件置位TF0。当CPU响应中断后，再由硬件将TF0清0。

TF1：与TF0类似。

TI、RI：串行口发送、接收中断，在串口中再讲解。

2、中断允许寄存器IE

在MCS－51中断系统中，中断的允许或禁止是由片内可进行位寻址的8位中断允许寄存器IE来控制的。见下表

其中EA是总开关，如果它等于0，则所有中断都不允许。

ES－串行口中断允许

ET1－定时器1中断允许

EX1－外中断1中断允许。

ET0－定时器0中断允许

EX0－外中断0中断允许。

如果我们要设置允许外中断1，定时器1中断允许，其它不允许，则IE可以是

即8CH，当然，我们也可以用位操作指令

SETB EA
SETB ET1

SETB EX1

来实现它。

3、五个中断源的自然优先级与中断服务入口地址

外中断0：0003H

定时器0：000BH

外中断1：0013H

定时器1：001BH

串口 ：0023H

它们的自然优先级由高到低排列。

写到这里，大家应当明白，为什么前面有一些程序一始我们这样写：

ORG 0000H

LJMP START

ORG 0030H

START：

。

。

。

这样写的目的，就是为了让出中断源所占用的向量地址。当然，在程序中没用中断时，直接从0000H开始写程序，在原理上并没有错，但在实际工作中最好不这样做。

优先级：单片机采用了自然优先级和人工设置高、低优先级的策略，即可以由程序员设定那些中断是高优先级、哪些中断是低优先级，由于只有两级，必有一些中断处于同一级别，处于同一级别的，就由自然优先级确定。

开机时，每个中断都处于低优先级，我们可以用指令对优先级进行设置。看表2

中断优先级中由中断优先级寄存器IP来高置的，IP中某位设为1，相应的中断就是高优先级，否则就是低优先级。

例：设有如下要求，将T0、外中断1设为高优先级，其它为低优先级，求IP的值。

IP的首3位没用，可任意取值，设为000，后面根据要求写就可以了

因此，最终，IP的值就是06H。

例：在上例中，如果5个中断请求同时发生，求中断响应的次序。

响应次序为：定时器0－＞外中断1－＞外中断0－＞实时器1－＞串行中断。

MCS－51的中断响应过程：

1、中断响应的条件：讲到这儿，我们依然对于计算机响应中断感到神奇，我们人可以响应外界的事件，是因为我们有多种“传感器“――眼、耳可以接受不同的信息，计算机是如何做到这点的呢？其实说穿了，一点都不希奇，MCS51工作时，在每个机器周期中都会去查询一下各个中断标记，看他们是否是“1“，如果是1，就说明有中断请求了，所以所谓中断，其实也是查询，不过是每个周期都查一下而已。这要换成人来说，就相当于你在看书的时候，每一秒钟都会抬起头来看一看，查问一下，是不是有人按门铃，是否有电话。。。。很蠢，不是吗？可计算机本来就是这样，它根本没人聪明。

了解了上述中断的过程，就不难解中断响应的条件了。在下列三种情况之一时，CPU将封锁对中断的响应：

CPU正在处理一个同级或更高级别的中断请求。

现行的机器周期不是当前正执行指令的最后一个周期。我们知道，单片机有单周期、双周期、三周期指令，当前执行指令是单字节没有关系，如果是双字节或四字节的，就要等整条指令都执行完了，才能响应中断（因为中断查询是在每个机器周期都可能查到的）。

当前正执行的指令是返回批令（RETI）或访问IP、IE寄存器的指令，则CPU至少再执行一条指令才应中断。这些都是与中断有关的，如果正访问IP、IE则可能会开、关中断或改变中断的优先级，而中断返回指令则说明本次中断还没有处理完，所以都要等本指令处理结束，再执行一条指令才可以响应中断。

2、中断响应过程

CPU响应中断时，首先把当前指令的下一条指令（就是中断返回后将要执行的指令）的地址送入堆栈，然后根据中断标记，将相应的中断入口地址送入PC，PC是程序指针，CPU取指令就根据PC中的值，PC中是什么值，就会到什么地方去取指令，所以程序就会转到中断入口处继续执行。这些工作都是由硬件来完成的，不必我们去考虑。这里还有个问题，大家是否注意到，每个中断向量地址只间隔了8个单元，如0003－000B，在如此少的空间中如何完成中断程序呢？很简单，你在中断处安排一个LJMP指令，不就可以把中断程序跳转到任何地方了吗？

一个完整的主程序看起来应该是这样的：

ORG 0000H

LJMP START

ORG 0003H

LJMP INT0 ；转外中断0

ORG 000BH

RETI ；没有用定时器0中断，在此放一条RETI，万一 “不小心“产生了中断，也不会有太大的后果。

。

。

。

。

中断程序完成后，一定要执行一条RETI指令，执行这条指令后，CPU将会把堆栈中保存着的地址取出，送回PC，那么程序就会从主程序的中断处继续往下执行了。注意：CPU所做的保护工作是很有限的，只保护了一个地址，而其它的所有东西都不保护，所以如果你在主程序中用到了如A、PSW等，在中断程序中又要用它们，还要保证回到主程序后这里面的数据还是没执行中断以前的数据，就得自己保护起来。

定时、中断练习一

1、利用定时器实现灯的闪烁

在学单片机时我们第一个例子就是灯的闪烁，那是用延时程序做的，现在回想起来，这样做不很恰当，为什么呢？我们的主程序做了灯的闪烁，就不能再干其它的事了，难道单片机只能这样工作吗？当然不是，我们可以用定时器来实现灯的闪烁的功能。

例1：查询方式

键入程序，看到了什么？灯在闪烁了，这可是用定时器做的，不再是主程序的循环了。简单地分析一下程序，为什么用JBC呢？TF0是定时/计数器0的溢出标记位，当定时器产生溢出后，该位由0变1，所以查询该位就可知宇时时间是否已到。该位为1后，要用软件将标记位清0，以便下一次定时是间到时该位由0变1，所以用了JBC指令，该指位在判1转移的同时，还将该位清0。

以上程序是可以实现灯的闪烁了，可是主程序除了让灯闪烁外，还是不能做其他的事啊！不，不对，我们可以在LOOP：……和AJMP LOOP指令之间插入一些指令来做其他的事情，只要保证执行这些指令的时间少于定时时间就行了。那我们在用软件延时程序的时候不是也可以用一些指令来替代DJNZ吗？是的，但是那就要求你精确计算所用指令的时间，然后再减去相应的DJNZ循环次数，很不方便，而现在只要求所用指令的时间少于定时时间就行，显然要求低了。当然，这样的方法还是不好，所以我们常用以下的方法来实现。

程序2：用中断实现

上面的例子中，定时时间一到，TF0由0变1，就会引发中断，CPU将自动转至000B处寻找程序并执行，由于留给定时器中断的空间只有8个字节，显然不足以写下所有有中断处理程序，所以在000B处安排一条跳转指令，转到实际处理中断的程序处，这样，中断程序可以写在任意地方，也可以写任意长度了。进入定时中断后，首先要保存当前的一些状态，程序中只演示了保存存ACC和PSW，实际工作中应该根据需要将可能会改变的单元的值都推入堆栈进行保护（本程序中实际不需保存护任何值，这里只作个演示）。

上面的两个程序运行后，我们发现灯的闪烁非常快，根本分辨不出来，只是视觉上感到灯有些晃动而已，为什么呢？我们可以计算一下，定时器中预置的数是5536，所以每计60000个脉冲就是定时时间到，这60000个脉冲的时间是多少呢？我们的晶振是12M，所以就是60000微秒，即60毫秒，因此速度是非常快的。如果我想实现一个1S的定时，该怎么办呢？在该晶振濒率下，最长的定时也就是65。536个毫秒啊！上面给出一个例子。

先自己分析一下，看看是怎么实现的？这里采用了软件计数器的概念，思路是这样的，先用定时/计数器0做一个50毫秒的定时器，定时是间到了以后并不是立即取反P10，而是将软件计数器中的值加1，如果软件计数器计到了20，就取反P10，并清掉软件计数器中的值，否则直接返回，这样，就变成了20次定时中断才取反一次P10，因此定时时间就延长了成了20*50即1000毫秒了。

这个思路在工程中是非常有用的，有的时候我们需要若干个定时器，可51中总共才有2个，怎么办呢？其实，只要这几个定时的时间有一定的公约数，我们就可以用软件定时器加以实现，如我要实现P10口所接灯按1S每次，而P11口所接灯按2S每次闪烁，怎么实现呢？对了我们用两个计数器，一个在它计到20时，取反P10，并清零，就如上面所示，另一个计到40取反P11，然后清0，不就行了吗？这部份的程序如下

程序一下载 代码下载 程序二下载 代码下载 程序三下载 代码下载 程序四下载 代码下载

您能用定时器的方法实现前面讲的流水灯吗？试试看。

定时/计数器实验2

前面我们做了定时器的实验，现在来看一看计数实验，在工作中计数通常会有两种要求：第一、将计数的值显示出来，第二、计数值到一定程度即中断报警。第一种如各种计数器、里程表，第二种如前面例中讲到的生产线上的计数。先看第一种吧。我们的硬件中是这样连线的：324构成的振荡器连到定时/计数器1的外部引脚T1上面，我们就利用这个来做一个计数实验，要将计数的值显示出来，当然最好用数码管了，可我们还没讲到这一部份，为了避免把问题复杂化，我们用P1口的8个LED来显示计到的数据。

程序如下：

ORG 0000H

AJMP START

ORG 30H

START:

MOV SP,#5FH

MOV TMOD,#01000000B ;定时/计数器1作计数用,0不用全置0

SETB TR1 ;启动计数器1开始运行.

LOOP: MOV A,TL0

MOV P1,A

AJMP LOOP

END

在硬件上用线将324的输出与T1连通(印板上有焊盘)运行这种程序，注意将板按正确的位置放置（LM324放在左手边，LED排列是按从高位到低们排列）看到什么？随着324后接的LED的闪烁，单片机的8只LED也在不断变化，注意观察，是不是按二进制：

00000000

00000001

00000010

00000011

。

。

。

这样的顺序在变呢？这就对了，这就是TL0中的数据。

程序二：

ORG 0000H

AJMP START

ORG 001BH

AJMP TIMER1 ;定时器1的中断处理

ORG 30H

START: MOV SP,#5FH

MOV TMOD,#01010000B ;定时/计数器1作计数用,模式1,0不用全置0

MOV TH1,#0FFH

MOV TL1,#0FAH ;预置值,要求每计到6个脉冲即为一个事件

SETB EA

SETB ET1 ;开总中断和定时器1中断允许

SETB TR1 ;启动计数器1开始运行.

AJMP $

TIMER1:

PUSH ACC

PUSH PSW

CPL P1.0 ;计数值到,即取反P1.0

MOV TH1,#0FFH

MOV TL1,#0FAH ;重置计数初值

POP PSW

POP ACC

RETI

END

上面这个程序完成的工作很简单，就是在每6个脉冲到来后取反一次P1。0，因此实验的结果应当是：LM324后接的LED亮、灭6次，则P1。0口所接LED亮或灭一次。这实际就是我们上面讲的计数器的第二种应用。

程序三：外部中断实验

ORG 0000H

AJMP START

ORG 0003H ;外部中断地直入口

AJMP INT0

ORG 30H

START: MOV SP,#5FH

MOV P1,#0FFH ;灯全灭

MOV P3,#0FFH ;P3口置高电平

SETB EA

SETB EX0

AJMP $

INT0:

PUSH ACC

PUSH PSW

CPL P1.0

POP PSW

POP ACC

RETI

END

本程序的功能很简单，按一次按键1（接在12引脚上的）就引发一次中断0，取反一次P1。0，因此理论上按一下灯亮，按一下灯灭，但在实际做实验时，可能会发觉有时不“灵”，按了它没反应，但在大部份时候是对的，这是怎么回事呢？我们在讲解键盘时再作解释，这个程序本身是没有问题的。

程序1下载 程序1代码 程序2下载 程序2代码 程序3下载 程序3代码

串行接口

概述

串行接口的一般概念 单片机与外界进行信息交换称之为通讯。

8051单片机的通讯方式有两种：

并行通讯:数据的各位同时发送或接收。

串行通讯:数据一位一位顺序发送或接收。参看下图：

串行通讯的方式：

异步通讯：它用一个起始位表示字符的开始，用停止位表示字符的结束。其每帧的格式如下：

在一帧格式中，先是一个起始位0，然后是8个数据位，规定低位在前，高位在后，接下来是奇偶校验位（可以省略），最后是停止位1。用这种格式表示字符，则字符可以一个接一个地传送。

在异步通讯中，CPU与外设之间必须有两项规定，即字符格式和波特率。字符格式的规定是双方能够在对同一种0和1的串理解成同一种意义。原则上字符格式可以由通讯的双方自由制定，但从通用、方便的角度出发，一般还是使用一些标准为好，如采用ASCII标准。

波特率即数据传送的速率，其定义是每秒钟传送的二进制数的位数。例如，数据传送的速率是120字符/s，而每个字符如上述规定包含10数位，则传送波特率为1200波特。

同步通讯：在同步通讯中，每个字符要用起始位和停止位作为字符开始和结束的标志，占用了时间；所以在数据块传递时，为了提高速度，常去掉这些标志，采用同步传送。由于数据块传递开始要用同步字符来指示，同时要求由时钟来实现发送端与接收端之间的同步，故硬件较复杂。

通讯方向：在串行通讯中，把通讯接口只能发送或接收的单向传送方法叫单工传送；而把数据在甲乙两机之间的双向传递，称之为双工传送。在双工传送方式中又分为半双工传送和全双工传送。半双工传送是两机之间不能同时进行发送和接收，任一时该，只能发或者只能收信息。

2．8051单片机的串行接口结构

8051串行接口是一个可编程的全双工串行通讯接口。它可用作异步通讯方式（UART），与串行传送信息的外部设备相连接，或用于通过标准异步通讯协议进行全双工的8051多机系统也可以通过同步方式，使用TTL或CMOS移位寄存器来扩充I/O口。

8051单片机通过引脚RXD（P3.0，串行数据接收端）和引脚TXD（P3.1，串行数据发送端）与外界通讯。SBUF是串行口缓冲寄存器，包括发送寄存器和接收寄存器。它们有相同名字和地址空间，但不会出现冲突，因为它们两个一个只能被CPU读出数据，一个只能被CPU写入数据。

串行口的控制与状态寄存器

串行口控制寄存器SCON

它用于定义串行口的工作方式及实施接收和发送控制。字节地址为98H，其各位定义如下表：

SM0、SM1：串行口工作方式选择位，其定义如下：

其中fosc为晶振频率

SM2：多机通讯控制位。在方式0时，SM2一定要等于0。在方式1中，当（SM2）=1则只有接收到有效停止位时，RI才置1。在方式2或方式3当（SM2）=1且接收到的第九位数据RB8=0时，RI才置1。

REN：接收允许控制位。由软件置位以允许接收，又由软件清0来禁止接收。

TB8: 是要发送数据的第9位。在方式2或方式3中，要发送的第9位数据，根据需要由软件置1或清0。例如，可约定作为奇偶校验位，或在多机通讯中作为区别地址帧或数据帧的标志位。

RB8：接收到的数据的第9位。在方式0中不使用RB8。在方式1中，若（SM2）=0，RB8为接收到的停止位。在方式2或方式3中，RB8为接收到的第9位数据。

TI： 发送中断标志。在方式0中，第8位发送结束时，由硬件置位。在其它方式的发送停止位前，由硬件置位。TI置位既表示一帧信息发送结束，同时也是申请中断，可根据需要，用软件查询的方法获得数据已发送完毕的信息，或用中断的方式来发送下一个数据。TI必须用软件清0。

RI： 接收中断标志位。在方式0，当接收完第8位数据后，由硬件置位。在其它方式中，在接收到停止位的中间时刻由硬件置位（例外情况见于SM2的说明）。RI置位表示一帧数据接收完毕，可用查询的方法获知或者用中断的方法获知。RI也必须用软件清0。

特殊功能寄存器PCON

PCON是为了在CHMOS的80C51单片机上实现电源控制而附加的。其中最高位是SMOD。

串行口的工作方式

8051单片机的全双工串行口可编程为4种工作方式，现分述如下：

方式0为移位寄存器输入/输出方式。可外接移位寄存器以扩展I/O口，也可以外接同步输入/输出设备。8位串行数据者是从RXD输入或输出，TXD用来输出同步脉冲。

输出 串行数据从RXD引脚输出，TXD引脚输出移位脉冲。CPU将数据写入发送寄存器时，立即启动发送，将8位数据以fos/12的固定波特率从RXD输出，低位在前，高位在后。发送完一帧数据后，发送中断标志TI由硬件置位。

输入 当串行口以方式0接收时，先置位允许接收控制位REN。此时，RXD为串行数据输入端，TXD仍为同步脉冲移位输出端。当（RI）=0和（REN）=1同时满足时，开始接收。当接收到第8位数据时，将数据移入接收寄存器，并由硬件置位RI。

下面两图分别是方式

方式1为波特率可变的10位异步通讯接口方式。发送或接收一帧信息，包括1个起始位0，8个数据位和1个停止位1。

输出 当CPU执行一条指令将数据写入发送缓冲SBUF时，就启动发送。串行数据从TXD引脚输出，发送完一帧数据后，就由硬件置位TI。

输入 在（REN）=1时，串行口采样RXD引脚，当采样到1至0的跳变时，确认是开始位0，就开始接收一帧数据。只有当（RI）=0且停止位为1或者（SM2）=0时，停止位才进入RB8，8位数据才能进入接收寄存器，并由硬件置位中断标志RI；否则信息丢失。所以在方式1接收时，应先用软件清零RI和SM2标志。

方式2

方式月为固定波特率的11位UART方式。它比方式1增加了一位可程控为1或0的第9位数据。

输出: 发送的串行数据由TXD端输出一帧信息为11位，附加的第9位来自SCON寄存器的TB8位，用软件置位或复位。它可作为多机通讯中地址/数据信息的标志位，也可以作为数据的奇偶校验位。当CPU执行一条数据写入SUBF的指令时，就启动发送器发送。发送一帧信息后，置位中断标志TI。

输入: 在（REN）=1时，串行口采样RXD引脚，当采样到1至0的跳变时，确认是开始位0，就开始接收一帧数据。在接收到附加的第9位数据后，当（RI）=0或者（SM2）=0时，第9位数据才进入RB8，8位数据才能进入接收寄存器，并由硬件置位中断标志RI；否则信息丢失。且不置位RI。再过一位时间后，不管上述条件时否满足，接收电路即行复位，并重新检测RXD上从1到0的跳变。

工作方式3

方式3为波特率可变的11位UART方式。除波特率外，其余与方式2相同。

波特率选择

如前所述，在串行通讯中，收发双方的数据传送率（波特率）要有一定的约定。在8051串行口的四种工作方式中，方式0和2的波特率是固定的，而方式1和3的波特率是可变的，由定时器T1的溢出率控制。

方式0

方式0的波特率固定为主振频率的1/12。

方式2

方式2的波特率由PCON中的选择位SMOD来决定，可由下式表示：

波特率=2的SMOD次方除以64再乘一个fosc，也就是当SMOD=1时，波特率为1/32fosc，当SMOD=0时，波特率为1/64fosc

3．方式1和方式3

定时器T1作为波特率发生器，其公式如下：

波特率=定时器T1溢出率

T1溢出率= T1计数率/产生溢出所需的周期数

式中T1计数率取决于它工作在定时器状态还是计数器状态。当工作于定时器状态时，T1计数率为fosc/12;当工作于计数器状态时，T1计数率为外部输入频率，此频率应小于fosc/24。产生溢出所需周期与定时器T1的工作方式、T1的预置值有关。

定时器T1工作于方式0：溢出所需周期数=8192-x

定时器T1工作于方式1：溢出所需周期数=65536-x

定时器T1工作于方式2：溢出所需周期数=256-x

因为方式2为自动重装入初值的8位定时器/计数器模式，所以用它来做波特率发生器最恰当。

当时钟频率选用11.0592MHZ时，取易获得标准的波特率，所以很多单片机系统选用这个看起来“怪”的晶振就是这个道理。

下表列出了定时器T1工作于方式2常用波特率及初值。

串行口应用编程实例

1． 串口方式0应用编程 8051单片机串行口方式0为移位寄存器方式，外接一个串入并出的移位寄存器，就可以扩展一个并行口。

例：用8051串行口外接CD4094扩展8位并行输出口，如图所示，8位并行口的各位都接一个发光二极管，要求发光管呈流水灯状态。 串行口方式0的数据传送可采用中断方式，也可采用查询方式，无论哪种方式，都要借助于TI或RI标志。串行发送时，可以靠TI置位（发完一帧数据后）引起中断申请，在中断服务程序中发送下一帧数据，或者通过查询TI的状态，只要TI为0就继续查询，TI为1就结束查询，发送下一帧数据。在串行接收时，则由RI引起中断或对RI查询来确定何时接收下一帧数据。无论采用什么方式，在开始通讯之前，都要先对控制寄存器SCON进行初始化。在方式0中将，将00H送SCON就可以了。

ORG 2000H

START: MOV SCON,#00H ;置串行口工作方式0

MOV A,#80H ;最高位灯先亮

CLR P1.0 ;关闭并行输出（避象传输过程中，各LED的"暗红"现象）

OUT0: MOV SBUF,A ;开始串行输出

OUT1: JNB TI,OUT1 ;输出完否

CLR TI ;完了，清TI标志，以备下次发送

SETB P1.0 ;打开并行口输出

ACALL DELAY ;延时一段时间

RR A ;循环右移

CLR P1.0 ;关闭并行输出

JMP OUT0 ;循环

说明：DELAY延时子程序可以用前面我们讲P1口流水灯时用的延时子程序，这里就不给出了。

二、异步通讯

org 0000H

AJMP START

ORG 30H

START:

mov SP,#5fh ;

mov TMOD,#20h ;T1: 工作模式2

mov PCON,#80h ;SMOD=1

mov TH1,#0FDH ;初始化波特率（参见表）

mov SCON,#50h ;Standard UART settings

MOV R0,#0AAH ;准备送出的数

SETB REN ;允许接收

SETB TR1 ;T1开始工作

WAIT:

MOV A,R0

CPL A

MOV R0,A

MOV SBUF,A

LCALL DELAY

JBC TI,WAIT1 ;如果TI等于1，则清TI并转WAIT1

AJMP WAIT

WAIT1: JBC RI,READ ;如果RI等于1，则清RI并转READ

AJMP WAIT1

READ:

MOV A,SBUF ;将取得的数送P1口

MOV P1,A

LJMP WAIT

DELAY: ;延时子程序

MOV R7,#0ffH

DJNZ R7,$

RET

END

将程序编译通过，写入芯片，插入实验板，用通读电缆将实验板与主机的串口相连就可以实验了。上面的程序功能很简单，就是每隔一段时间向主机轮流送数55H和AAH，并把主机送去的数送到P1口。可以在PC端用串口精灵来做实验。串口精灵在我主页上有下载。运行串口精灵后，按主界面上的“设置参数”按钮进入“设置参数”对话框，按下面的参数进行设置。注意，我的机器上用的是串口2，如果你不是串口2，请自行更改串口的设置。

设置完后，按确定返回主界面，注意右边有一个下拉列表，应当选中“按16进制”。然后按“开始发送”、“开始接收”就可以了。按此设置，实验板上应当有两只灯亮，6只灯灭。大家可以自行更改设置参数中的发送字符如55，00，FF等等，观察灯的亮灭，并分析原因，也可以在主界面上更改下拉列表中的“按16进制”为“按10进制”或“按ASCII字符”来观察现象，并仔细分析。这对于大家理解16进制、10进制、ASCII字符也是很有好处的。程序本身很简单，又有注释，这里就不详加说明了。

三、上述程序的中断版本

org 0000H

AJMP START

org 0023h

AJMP SERIAL ;

ORG 30H

START:

mov SP,#5fh ;

mov TMOD,#20h ;T1: 工作模式2

mov PCON,#80h ;SMOD=1

mov TH1,#0FDH ;初始化波特率（参见表）

mov SCON,#50h ;Standard UART settings

MOV R0,#0AAH ;准备送出的数

SETB REN ;允许接收

SETB TR1 ;T1开始工作

SETB EA ;开总中断

SETB ES ;开串口中断

SJMP $

SERIAL:

MOV A,SBUF

MOV P1,A

CLR RI

RETI

END

本程序没有写入发送程序，大家可以自行添加。

常用接口电路及其编程

LED数码显示器的连接与编程

在单片机系统中，通常用LED数码显示器来显示各种数字或符号。由于它具有显示清晰、亮度高、使用电压低、寿命长的特点，因此使用非常广泛。

1. 
   
2. 
   

   八段LED显示器

   
   
   
   

   引入：还记得我们小时候玩的“火柴棒游戏”吗，几根火柴棒组合起来，可以拼成各种各样的图形，LED显示器实际上也是这么一个东西。

   
   
   
   

   八段LED显示器由8个发光二极管组成。基中7个长条形的发光管排列成“日”字形，另一个贺点形的发光管在显示器的右下角作为显示小数点用，它能显示各种数字及部份英文字母。LED显示器有两种不同的形式：一种是8个发光二极管的阳极都连在一起的，称之为共阳极LED显示器；另一种是8个发光二极管的阴极都连在一起的，称之为共阴极LED显示器。如下图所示。`

   
   

   共阴和共阳结构的LED显示器各笔划段名和安排位置是相同的。当二极管导通时，相应的笔划段发亮，由发亮的笔划段组合而显示的各种字符。8个笔划段hgfedcba对应于一个字节（8位）的D7 D6 D5 D4 D3 D2 D1 D0,于是用8位二进制码就可以表示欲显示字符的字形代码。例如，对于共阴LED显示器，当公共阴极接地（为零电平），而阳极hgfedcba各段为0111011时，显示器显示"P"字符，即对于共阴极LED显示器，“P”字符的字形码是73H。如果是共阳LED显示器，公共阳极接高电平，显示“P”字符的字形代码应为10001100（8CH）。这里必须注意的是：很多产品为方便接线，常不按规则的方法去对应字段与位的关系，这时字形码就必须根据接线来自行设计了，后面我们会给出一个例子。

   
   
   
   
3. 
   

   静态显示接口

   
   

在单片机应用系统中，显示器显示常用两种方法：静态显示和动态扫描显示。所谓静态显示，就是每一个显示器都要占用单独的具有锁存功能的I/O接口用于笔划段字形代码。这样单片机只要把要显示的字形代码发送到接口电路，就不用管它了，直到要显示新的数据时，再发送新的字形码，因此，使用这种方法单片机中CPU的开销小。可以提供单独锁存的I/O接口电路很多，这里以常用的串并转换电路74LS164为例，介绍一种常用静态显示电路，以使大家对静态显示有一定的了解。

MCS-51单片机串行口方式押为移们寄存器方式，外接6片74LS164作为6位LED显示器的静态显示接口，把8031的RXD作为数据输出线，TXD作为移位时钟脉冲。74LS164为TTL单向8位移位寄存器，可实现串行输入，并行输出。其中A、B（第1、2脚）为串行数据输入端，2个引脚按逻辑与运算规律输入信号，公一个输入信号时可并接。T（第8脚）为时钟输入端，可连接到串行口的TXD端。每一个时钟信号的上升沿加到T端时，移位寄存器移一位，8个时钟脉冲过后，8位二进制数全部移入74LS164中。R（第9脚）为复位端，当R=0时，移位寄存器各位复0，只有当R=1时，时钟脉冲才起作用。Q1…Q8（第3-6和10-13引脚）并行输出端分别接LED显示器的hg---a各段对应的引脚上。关于74LS164还可以作如下的介绍：所谓时钟脉冲端，其实就是需要高、低、高、低的脉冲，不管这个脉冲是怎么来的，比如，我们用根电线，一端接T，一端用手拿着，分别接高电平、低电平，那也是给出时钟脉冲，在74LS164获得时钟脉冲的瞬间（再讲清楚点，是在脉冲的沿），如果数据输入端（第1，2引脚）是高电平，则就会有一个1进入到74LS164的内部，如果数据输入端是低电平，则就会有一个0进入其内部。在给出了8个脉冲后，最先进入74LS164的第一个数据到达了最高位，然后再来一个脉冲会有什么发生呢？再来一个脉冲，第一个脉冲就会从最高位移出，就象车站排队买票，栏杆就那么长，要从后面进去一个人，前面必须要从前面走出去一个人才行。

搞清了这一点，下面让我们来看电路，6片7LS164首尾相串，而时钟端则接在一起，这样，当输入8个脉冲时，从单片机RXD端输出的数据就进入到了第一片74LS164中了，而当第二个8个脉冲到来后，这个数据就进入了第二片74LS164，而新的数据则进入了第一片74LS164，这样，当第六个8个脉冲完成后，首次送出的数据被送到了最左面的164中，其他数据依次出现在第一、二、三、四、五片74LS164中。有个问题，在第一个脉冲到来时，除了第一片74LS164中接收数据外，其他各片在干吗呢？它们也在接收数据，因为它们的时钟端都是被接在一起的，可是数据还没有送到其他各片呢，它们在接收什么数据呢？。。。。。。其实所谓数据不过是一种说法而已，实际就是电平的高低，当第一个脉冲到来时，第一片164固然是从单片机接收数据了，而其它各片也接到前一片的Q8上，而Q8是一根电线，在数字电路中它只可能有两种状态：低电平或高电平，也就是“0”和“1”。所以它的下一片74LS164也相当于是在接收数据啊。只是接收的全部是0或1而已。这个问题放在这儿说明，可能有朋友不屑一顾，而有的朋友可能还是不清楚，这实际上涉及到数的本质的问题，如果不懂的，请仔细思考，并找一些数字电路的数，理解164的工作原理，再来看这个问题，或者去看看我的另一篇文章《初学单片机易掌握的概念》。务必搞懂，搞懂了这一点，你的级别就高过初学者，可谓入门者了。

入口：把要显示的数分别放在显示缓冲区60H-65H共6个单元中，并且分别对应各个数码管LED0-LED5。

出口：将预置在显示缓冲区中的6个数成相应的显示字形码，然后输出到显示器中显示。

显示程序如下：

DISP: MOV SCON,#00H ;初始化串行口方式0

MOV R1,#06H ;显示6位数

MOV R0,#65H ;60H-65H为显示缓冲区

MOV DPTR,#SEGTAB ;字形表的入口地址

LOOP:

MOV A,@R0 ;取最高位的待显示数据

MOVC A,@A+DPTR ;查表获取字形码

MOV SBUF,A ;送串口显示

DELAY: JNB TI,DELAY ;等待发送完毕

CLR TI ;清发送标志

DEC R0 ;指针下移一位，准备取下一个待显示数

DJNZ R1,LOOP ;直到6个数据全显示完。

RET

SETTAB: ;字形表，前面有介绍，以后我们再介绍字形表的制作。

DB 03H 9FH 27H 0DH 99H 49H 41H 1FH 01H 09H 0FFH

; #9; 0 1 2 3 4 5 6 7 8 9 消隐码

测试用主程序

ORG 0000H

AJMP START

ORG 30H

START: MOV SP,#6FH

MOV 65H,#0

MOV 64H,#1

MOV 63H,#2

MOV 62H,#3

MOV 61H,#4

MOV 60H,#5

LCALL DISP

SJMP $

如果按图示数码管排列，则以上主程序将显示的是543210，想想看，如果要显示012345该怎样送数？

下面我们来分析一下字形表的制作问题。先就上述“标准”的图形来看吧。写出数据位和字形的对应关系并列一个表如下（设为共阳型，也就是相应的输出位为0时笔段亮）

如何，字形表会做了吧，就是这样列个表格，根据要求（0亮或1亮）写出相应位的0和1，就成了。做个练习，写出A-F的字形码吧。

如果为了接线方便而打乱了接线的顺序，那么字形表又该如何接呢？也很简单，一样地列表啊。以新实验板为例，共阳型。接线如下：

P0.7 P0.6 P0.5 P0.4 P0.3 P0.2 P0.1 P0.0

C E H D G F A B

则字形码如下所示：

;0 00101000 28H

;1 01111110 7EH

;2 10100100 0A4H

;3 01100100 64H

;4 01110010 72H

;5 01100001 61H

;6 00100001 21H

;7 01111100 7CH

;8 00100000 20H

;9 01100000 60H

作为练习，大家写出A-F的字形代码。

本来这里是讲解显示器的静态接口的，到此应当可算结束了，但是我还想接着上面讲到的数的本质的问题再谈一点。单片机中有一些术语、名词本来是帮助我们理解事物的，但有时我们会被这些术语的相关语义所迷惑，以致不能进一步认清他们的本质，由此往往陷入困惑的境界。只有深入地了解了74LS164的工作特性，才能真正理解何谓串行的数据。有兴趣的朋友还可以再看看我网站上“其他资料”中的“银行利率屏的设计”一文。

动态扫描显示接口

   动态扫描显示接口是单片机中应用最为广泛的一种显示方式之一。其接口电路是把所有显示器的8个笔划段a-h同名端连在一起，而每一个显示器的公共极COM是各自独立地受I/O线控制。CPU向字段输出口送出字形码时，所有显示器接收到相同的字形码，但究竟是那个显示器亮，则取决于COM端，而这一端是由I/O控制的，所以我们就可以自行决定何时显示哪一位了。而所谓动态扫描就是指我们采用分时的方法，轮流控制各个显示器的COM端，使各个显示器轮流点亮。

   在轮流点亮扫描过程中，每位显示器的点亮时间是极为短暂的（约1ms），但由于人的视觉暂留现象及发光二极管的余辉效应，尽管实际上各位显示器并非同时点亮，但只要扫描的速度足够快，给人的印象就是一组稳定的显示数据，不会有闪烁感。

   下图所示就是我们的实验板上的动态扫描接口。由89C51的P0口能灌入较大的电流，所以我们采用共阳的数码管，并且不用限流电阻，而只是用两只1N4004进行降压后给数码管供电，这里仅用了两只，实际上还可以扩充。它们的公共端则由PNP型三极管8550控制，显然，如果8550导通，则相应的数码管就可以亮，而如果8550截止，则对应的数码管就不可能亮，8550是由P2.7，P2.6控制的。这样我们就可以通过控制P27、P26达到控制某个数码管亮或灭的目的。

下面的这个程序，就是用实验板上的数码管显示0和1。

FIRST EQU P2.7 ;第一位数码管的位控制

SECOND EQU P2.6 ;第二位数码管的位控制

DISPBUFF EQU 5AH ;显示缓冲区为5AH和5BH

ORG 0000H

AJMP START

ORG 30H

START:

MOV SP,#5FH ;设置堆栈

MOV P1,#0FFH

MOV P0,#0FFH

MOV P2,#0FFH ;初始化，所显示器，LED灭

MOV DISPBUFF,#0 ;第一位显示0

MOV DISPBUFF+1,#1 ;第二握显示1