原创 Arduino红外蔽障小车的实践(视频)

先看看小车的安装步骤：

第一步：

后面两个电机带动轮子，前面是一个万向滚珠，实际上这个小车是两轮小车，前面的滚珠作为三点支撑。

第二步：

在“下”安装盘的前方，安装电池盒，并焊接了一个电源小开关，这个开关可以装在“上”安装盘上，方便接通电源，运行程序。

第三步：

装上电池，这个电池需2400mA充电电池，5个，最好不用普通的碱性电池，碱性电池容量小，当小车负载大时，由于电流补充不够，导致电压下降，甚至低于AVR单片机对电压的要求，程序就会出错，小车不听指挥了。

第四步：

把Arduino控制器、L298驱动板和传感器扩展板层叠一起放在“上”安装盘上，把一个电位计模块也装好，这个电位计模块可以调节小车速度。安装红外测距传感器支架，这个支架可以朝上安装也可以朝下安装，我觉得朝下安装好些，为啥？如果朝上安装，红外测距传感器就看不到低矮的障碍物了！

第五步：

这是个总装图，要利用一些孔把电机、红外、电源的线理好，接好。看看那个小电源开关已经稳妥地安装到了“上”安装盘。

红外蔽障传感器的后端有个小旋钮，可以用“一字起”工具旋转，以调节测量距离，我通过调节，把测量距离设为20厘米左右。这个红外传感器如果在20厘米内检测到障碍物，则发低电平，否则为高电平。

红外线蔽障小车的Arduino程序，程序注释较清楚。

int IR_right=9;//定义右侧避障传感器接口
int IR_left=10;//定义中间避障传感器接口
int IR_middle=8;//定义左侧避障传感器接口
int E_right =5; //连接电机1的使能端口到数字接口5
int M_right =4; //连接电机1的转向端口到数字接口4
int E_left = 6;//连接电机2的使能端口到数字接口6
int M_left=7; //连接电机2的转向端口到数字接口5
int potpin=0;//定义电位计相连的模拟接口0上
float velocity;//车速调节
void setup()
{
   //给各数字接口设置输入输出状态  
   pinMode(M_right, OUTPUT);
   pinMode(E_right, OUTPUT);
   pinMode(M_left, OUTPUT);
   pinMode(E_left, OUTPUT);
   pinMode(IR_right,INPUT);
   pinMode(IR_left, INPUT);
   pinMode(IR_middle, INPUT);
}
void advance()//前进
{
     digitalWrite(M_right,LOW);
     analogWrite(E_right,int(velocity));
     digitalWrite(M_left,HIGH);
     analogWrite(E_left,int(velocity));
}
void back()//后退
{
     digitalWrite(M_right,HIGH);
     analogWrite(E_right,int(velocity));
     digitalWrite(M_left,LOW);
     analogWrite(E_left,int(velocity));
}
void right()//右转
{
     digitalWrite(M_right,HIGH);
     analogWrite(E_right,int(velocity));
     digitalWrite(M_left,HIGH);
     analogWrite(E_left,int(velocity));
}
void left()//左转
{
     digitalWrite(M_right,LOW);
     analogWrite(E_right,int(velocity));
     digitalWrite(M_left,LOW);
     analogWrite(E_left,int(velocity));
}
void Stop()//停止
{
     digitalWrite(E_right, LOW); //右电机停
     digitalWrite(E_left, LOW); //左电机停
}
void loop()
{
   //读电位计给出的车速调节值
   velocity=(float)analogRead(potpin)/1023*255;
    int Right,Left, Middle;
   //读红外蔽障传感器的信号
    Right=digitalRead(IR_right);
    Left=digitalRead(IR_left);
    Middle=digitalRead(IR_middle);
    //如果右、中、左三个红外为高电平，前方没有障碍
    if(Right==HIGH && Middle==HIGH && Left==HIGH)
    advance();//前进
    //如果右、中、左三个红外为低电平，前方有障碍，
    //这样可以使小车从死角出来
    if(Right==LOW && Middle==LOW  && Left==LOW )
      {
        back();//后退
        delay(500);//后退时间 
        right();//右转
        delay(300);//右转时间      
      }
    //如果中红外为低电平，前方有障碍
    if(Right==HIGH && Middle==LOW && Left==HIGH  )
     {
        back();//后退
        delay(500);//后退时间 
        right();//右转
        delay(300);//右转时间
     }
     //面对夹缝，小车退回
     if(Right==LOW && Middle==HIGH  && Left==LOW )
      {
        back();//后退
        delay(500);//后退时间 
        right();//右转
        delay(300);//右转时间
      }
    //如果中、左红外为低电平，左边有障碍
    if(Right==HIGH && Middle==LOW && Left==LOW  )
    right();//右转
    //如果左红外为低电平，左边有障碍
    if(Right==HIGH && Middle==HIGH && Left==LOW)
    right();//右转
    //如果右、中红外为低电平，右边有障碍
    if(Right==LOW && Middle==LOW  && Left==HIGH )
    left();//左转
    //如果右红外为低电平，右边有障碍
    if(Right==LOW && Middle==HIGH  && Left==HIGH )
    left();//左转
}

实验照片