我决定自行编写示例，说明如何将Arduino设为睡眠状态。你可能会感到疑惑，这有什么必要呢？答案是：如果你制作的项目是由电池供电的话，那么这一设置就会非常有用。让Arduino进入睡眠模式状态可降低电流消耗，从而延长项目的运行时间，而不必频繁更换电池。在许多IOT项目中亦是如此，因为并不需要单片机或外部器件一直运行。
在启动示例代码中，我们用了两个按钮和两个LED来显示何时唤醒电路板以及何时按下中断按钮。当电路板被唤醒时，连接到引脚13的LED将开始闪烁。当按下连接到引脚11的按钮时，将使Arduino进入睡眠模式，而引脚13的LED也将停止闪烁。要唤醒电路板，只需按下连接到引脚2的按钮即可。按下此按钮时，连接到引脚10的LED将亮起，以表示中断已激活。

启动示例代码


  1. //These are the two libraries that are needed
  2. #include <avr/interrupt.h>
  3. #include <avr/sleep.h>

  5. /* Here we set up our inputs and outputs.  LEDs connected to pins 10 and 13 and pushbuttons attached to 2 and 12 */
  6. int ledPin = 13;
  7. int sleepPin = 12;
  8. int interruptPin = 10;
  9. int wakePin = 2;
  10. //sleepStatus is set up to keep track of the button input on pin 12.
  11. int sleepStatus = 0;

  13. void setup()
  14. {
  15.   pinMode(ledPin, OUTPUT);        
  16.   pinMode(interruptPin, OUTPUT);   
  17.   pinMode(sleepPin, INPUT_PULLUP);  
  18.   pinMode(wakePin, INPUT_PULLUP);

  20. /* Next we have to enable an interrupt.  

  22. The function is set up like this attachInterrupt(pin, function, triggerMode)  

  24. PIN – can be either a 0 to call out digital pin 2 or 1 to call out digital pin 3.

  26. FUNCTION – This is the function that will be run while in the interrupt

  28. TRIGGER MODE – this will be the mode of the interrupt pin.  
  29. It can be one the following:
  30.         LOW – a low level trigger
  31.         CHANGE – a change in level trigger
  32.         RISING – a rising edge trigger
  33.         FALLING – a falling edge trigger

  35. The IDLE sleep mode is the only mode that can use CHANGE, RISING, and FALLING modes.*/


  38. attachInterrupt(0, wakeUpNow, LOW);
  39. }

  41. void sleepNow()
  42. {
  43. //print message to serial monitor to let the user know board has gone to sleep
  44. Serial.println("going to sleep");
  45. //delay is added to allow user to get the full message on the serial monitor before going to sleep
  46. delay(15);

  48. //enables the sleep mode
  49. sleep_enable();

  51. // This is where we enable the interrupt, the reason it is done here is so that if the button is pressed accidently it doesn’t interrupt the running program.  
  52. attachInterrupt(0,wakeUpNow, LOW);


  55. /* The next line is where we choose the sleep mode we want to use for this code.  There are a few options to choose from, each with their own uses.  For more information on the sleep modes, please review the Atmega8 datasheet at [http://ww1.microchip.com/downloads/en/DeviceDoc/ATmega48A-PA-88A-PA-168A-PA-328-P-DS-DS40002061A.pdf](http://ww1.microchip.com/downloads/en/DeviceDoc/ATmega48A-PA-88A-PA-168A-PA-328-P-DS-DS40002061A.pdf)

  57. The 5 different options for sleep modes, they are listed below from least power savings to most power savings:
  58.         SLEEP_MODE_IDLE
  59.         SLEEP_MODE_ADC
  60.         SLEEP_MODE_PWR_SAVE
  61.         SLEEP_MODE_STANDBY
  62.         SLEEP_MODE_PWR_DOWN

  64. For this sketch, we will be using the most power savings possible so we choose SLEEP_MODE_PWR_DOWN */

  66. //sleep mode is set here
  67. set_sleep_mode(SLEEP_MODE_PWR_DOWN);


  70. //This is where the device is actually put to sleep
  71. sleep_mode();

  73. //Here is where the device begins to wake up.

  75. //First thing that is done is to disable the sleep mode
  76. sleep_disable();

  78. //disables the interrupt on pin 2 so the wakeUpNow code will not be executed during normal run time
  79. detachInterrupt(0);

  81. //wait 1 second so the user can notice the LED signaling the interrupt
  82. delay(1000);
  83. digitalWrite (interruptPin, LOW);
  84. }

  86. void wakeUpNow()  //This is the code that runs when the interrupt button is pressed and interrupts are enabled
  87. {
  88. digitalWrite(interruptPin, HIGH);
  89. }

  91. void loop()
  92. {
  93. // turns the LED on
  94.   digitalWrite(ledPin, HIGH);   
  95. // waits for a second         
  96.   delay(1000);         
  97. // turns the LED off                  
  98.   digitalWrite(ledPin, LOW);
  99. // waits for a second            
  100.   delay(1000);         
  101. //This is where the sleep pin is read.  It is only active when the LED is off.                 
  102.   sleepStatus = digitalRead(sleepPin);   

  104. //If button is pressed, device will run the sleepNow function                                         
  105.   if (sleepStatus == LOW) {            
  106.       sleepNow();                     
  107.       }
  108. }

初始代码接线图

添加实时时钟以唤醒 Arduino


接下来，我们将添加一个RTC（而非按钮）来控制Arduino的睡眠模式和唤醒。我在此项目中使用的是来自Adafruit的物料1528-1598-ND 15。选择它的主要原因是其配备了内置中断。我原来使用的是DS1307分线板，但我很快发现它并不支持中断，因此无法用于此项目。我还针对此项目下载了一些库。以下是指向我下载.zip库文件的链接。

指向库的链接：
https://github.com/PaulStoffregen/Time——Arduino的计时库
https://github.com/JChristensen/DS3232RTC——适用于DS3231，包含唤醒Arduino所需的提醒

添加 RTC 的代码
  1. #include <avr/interrupt.h>
  2. #include <avr/sleep.h>
  3. #include <DS3232RTC.h>      // https://github.com/JChristensen/DS3232RTC  this is the library for the DS2331 RTC


  6. //RTC Module global variables

  8. // Sets the wakeup interval in minutes
  9. const int time_interval = 5;
  10. // LED connected to digital pin 13
  11. int ledPin = 13;            
  12. // active LOW, RTC will interrupt this pin momentarily to wake up
  13. int wakePin = 2;            


  16. void setup() {

  18.   // set up the serial monitor
  19. Serial.begin(9600);
  20. //Set up the led pin as an output
  21.   pinMode(ledPin, OUTPUT);
  22. //Set pin d2 to input using the built-in pullup resistor
  23.   pinMode(wakePin, INPUT_PULLUP);
  24. //turning LED on
  25.   digitalWrite(ledPin, HIGH);


  28. // These next few lines of code initialize the alarms to known values, clear the flags, and clear the alarm interrupt flags
  29.   RTC.setAlarm(ALM1_MATCH_DATE, 0, 0, 0, 1);
  30.   RTC.setAlarm(ALM2_MATCH_DATE, 0, 0, 0, 1);
  31.   RTC.alarm(ALARM_1);
  32.   RTC.alarm(ALARM_2);
  33.   RTC.alarmInterrupt(ALARM_1, false);
  34.   RTC.alarmInterrupt(ALARM_2, false);
  35.   RTC.squareWave(SQWAVE_NONE);

  37.   /* Uncomment this section to set the time on the RTC.  Make sure to comment out after the first time
  38.      it is set or you will continue to reset the time everytime the sketch is uploaded.  Also note that the clock is 24 hour format.

  40.     tmElements_t tm;
  41.    // the next few lines set the clock to the correct hour, minute, and second.  Remember 24 hour format so 4pm = hour 16
  42.     tm.Hour = 8;               
  43.     tm.Minute = 19;
  44.     tm.Second = 00;
  45.    
  46.    // set the correct date on the RTC
  47.     tm.Day = 04;
  48.     tm.Month = 5;
  49.     tm.Year = 2019 - 1970; // in order to set the year correctly, just change the 2019 and leave the “- 1970” to get the correct offset
  50.    
  51.     RTC.write(tm);    // write the date and time to the RTC
  52.          
  53.   */

  55.   
  56.   time_t t; //create a temporary time variable so we can set the time and read the time from the RTC
  57.   t = RTC.get(); //Gets the current time of the RTC
  58.   RTC.setAlarm(ALM1_MATCH_MINUTES , 0, minute(t) + time_interval, 0, 0); // Setting alarm 1 to go off in the amount of minutes that we have the time interval constant set to
  59.   RTC.alarm(ALARM_1); // clear the alarm flag
  60.   RTC.squareWave(SQWAVE_NONE); // configure the INT/SQW pin for "interrupt" operation (disable square wave output)
  61.   RTC.alarmInterrupt(ALARM_1, true); // enable interrupt output for Alarm 1
  62. }



  66. void loop() {
  67.   delay(5000);//wait 5 seconds before going to sleep. When in a project, we would it is best to make this short as possible
  68.   sleepNow();  // run the sleepNow function

  70. }


  73. void sleepNow() {
  74.   sleep_enable();//Enabling sleep mode
  75.   attachInterrupt(0, wakeUpNow, LOW);//attaching a interrupt to pin d2
  76.   set_sleep_mode(SLEEP_MODE_PWR_DOWN);//Setting the sleep mode, in our case full sleep

  78.   digitalWrite(ledPin, LOW); //turning LED off
  79.   time_t t;// creates temporary time variable
  80.   t = RTC.get(); //gets current time from RTC
  81.   Serial.println("Sleep  Time: " + String(hour(t)) + ":" + String(minute(t)) + ":" + String(second(t))); //prints time stamp on serial monitor
  82.   delay(1000); //wait one second to allow the LED to be turned off before going to sleep
  83.   sleep_cpu();//heres where the Arduino is actually put to sleep
  84.   

  86.   Serial.println("just woke up!");//next line of code executed after the interrupt
  87.   digitalWrite(ledPin, HIGH); //turns the LED on
  88.   t = RTC.get();//get the new time from the RTC
  89.   Serial.println("WakeUp Time: " + String(hour(t)) + ":" + String(minute(t)) + ":" + String(second(t))); //Prints time stamp
  90.   
  91. //Set New Alarm
  92.   int alarmTime = 0; //temporary variable to store the new alarm time in minutes
  93.   
  94. //the next few lines are to roll the alarm over when it gets near the next hour
  95. if (minute(t) <= (60-time_interval))
  96.   {
  97.     alarmTime = minute(t) + time_interval;
  98.   }
  99.   else
  100.   {
  101.     alarmTime = (minute(t) + time_interval) - 60;
  102.   }

  104.   RTC.setAlarm(ALM1_MATCH_MINUTES , 0, alarmTime, 0, 0); // set new alarm


  107. // The next few lines of code I use for troubleshooting.  This way I can make sure the clock is waking up at the correct time

  109. Serial.print("The next alarm will go off at: ");
  110.    
  111. //These lines are to print the correct hour that the next alarm will go off
  112. if ((minute(t) <= 60-time_interval) && (hour(t) <= 22))
  113.     {
  114.       Serial.print(hour(t));
  115.     }
  116.     else if ((minute(t) >= 60-time_interval) && (hour(t) <= 22))
  117.     {
  118.       Serial.print(hour(t) + 1);
  119.     }
  120.     else
  121.     {
  122.       Serial.print(0);
  123.     }
  124.   
  125.     Serial.print(":"); // print a colon symbol
  126.    
  127. //print the correct minute, including leading zero if less than 10
  128. if (alarmTime <= 9)
  129.     {
  130.       Serial.print("0");
  131.     }
  132.     Serial.println(alarmTime);

  134.   //Last thing we do is clear the alarm flag
  135.   RTC.alarm(ALARM_1);

  137. }

  139. void wakeUpNow()  //This is the code that happens when the interrupt is activated
  140. {
  141.   Serial.println("Interrrupt Fired");//Print message to serial monitor
  142.   sleep_disable();//Disable sleep mode
  143.   detachInterrupt(0); //Removes the interrupt from pin 2;
  144. }

RTC 接线图



添加土壤湿度传感器和温度 / 湿度传感器
为了展示这类传感器的使用示例，我决定制作一个独立的装置监控系统。为此，我将使用土壤湿度探针（1568-1670-ND 1）和温度/湿度传感器（1528-1172-ND 1）。该程序现在要做的是检查土壤水份含量和温度。我决定省略此代码草稿中的湿度功能，但只需几行代码就可以再添加回来。
该监控系统会进行检查，以确保土壤湿度不会过低。如果水分含量低于一定水平，系统就会启动水泵或电磁阀。在本例中，我将LED用作指示器，以代替水泵或电磁阀。
对于此代码草稿，你需要安装MPL115A2库，该库可通过Manage Libraries Button进行安装（位于Include Library下的Sketch Menu中），或者你也可以通过以下链接找到zip文件：GitHub - adafruit/Adafruit_MPL115A2: Driver for the Adafruit MPL115A2 barometric pressure sensor breakout

添加温度 / 湿度传感器和土壤湿度传感器的代码

  1. #include <avr/interrupt.h>
  2. #include <avr/sleep.h>
  3. #include <DS3232RTC.h>      // https://github.com/JChristensen/DS3232RTC  this is the library for the DS2331 RTC
  4. #include <Wire.h>
  5. #include <Adafruit_MPL115A2.h>

  7. Adafruit_MPL115A2 mpl115a2;

  9. //RTC Module global variables

  11. // Sets the wakeup interval in minutes
  12. const int time_interval = 5;
  13. // LED connected to digital pin 13
  14. int ledPin = 13;            
  15. // active LOW, RTC will interrupt this pin momentarily to wake up
  16. int wakePin = 2;            
  17. // LED connected to digital pin 10
  18. int pumpLED = 10;
  19. //variable for storing the soil moisture value
  20. int moistureVal = 0;
  21. //input for the moisture sensor
  22. int soilPin = A0;
  23. //pin used to power the soil moisture sensor
  24. int soilPower = 7;

  26. void setup() {

  28. // set up the serial monitor
  29.   Serial.begin(9600);
  30. //Set up the led pin as an output
  31.   pinMode(ledPin, OUTPUT);
  32. //Set pin d2 to input using the built-in pullup resistor
  33.   pinMode(wakePin, INPUT_PULLUP);
  34. //turning LED on
  35.   digitalWrite(ledPin, HIGH);
  36. //Set D7 as an OUTPUT
  37.   pinMode(soilPower, OUTPUT);
  38. // Set to LOW so no power is flowing through the sensor
  39.   digitalWrite(soilPower, LOW);
  40. //Set D10 as an output
  41.   pinMode(pumpLED, OUTPUT);
  42. //starting the temp/humidity sensor
  43.   mpl115a2.begin();

  45. // These next few lines of code initialize the alarms to known values, clear the flags, and clear the alarm interrupt flags
  46.   RTC.setAlarm(ALM1_MATCH_DATE, 0, 0, 0, 1);
  47.   RTC.setAlarm(ALM2_MATCH_DATE, 0, 0, 0, 1);
  48.   RTC.alarm(ALARM_1);
  49.   RTC.alarm(ALARM_2);
  50.   RTC.alarmInterrupt(ALARM_1, false);
  51.   RTC.alarmInterrupt(ALARM_2, false);
  52.   RTC.squareWave(SQWAVE_NONE);

  54.   /* Uncomment this section to set the time on the RTC.  Make sure to comment out after the first time
  55.      it is set or you will continue to reset the time everytime the sketch is uploaded.  Also note that the clock is 24 hour format.

  57.     tmElements_t tm;
  58.    // the next few lines set the clock to the correct hour, minute, and second.  Remember 24 hour format so 4pm = hour 16
  59.     tm.Hour = 8;               
  60.     tm.Minute = 19;
  61.     tm.Second = 00;
  62.    
  63.    // set the correct date on the RTC
  64.     tm.Day = 04;
  65.     tm.Month = 5;
  66.     tm.Year = 2019 - 1970; // in order to set the year correctly, just change the 2019 and leave the “- 1970” to get the correct offset
  67.    
  68.     RTC.write(tm);    // write the date and time to the RTC
  69.          
  70.   */

  72.   
  73.   time_t t; //create a temporary time variable so we can set the time and read the time from the RTC
  74.   t = RTC.get(); //Gets the current time of the RTC
  75.   RTC.setAlarm(ALM1_MATCH_MINUTES , 0, minute(t) + time_interval, 0, 0); // Setting alarm 1 to go off in the amount of minutes that we have the time interval constant set to
  76.   RTC.alarm(ALARM_1); // clear the alarm flag
  77.   RTC.squareWave(SQWAVE_NONE); // configure the INT/SQW pin for "interrupt" operation (disable square wave output)
  78.   RTC.alarmInterrupt(ALARM_1, true); // enable interrupt output for Alarm 1
  79. }



  83. void loop() {
  84.   delay(5000);//wait 5 seconds before going to sleep. When in a project, we would it is best to make this short as possible
  85.   sleepNow();  // run the sleepNow function

  87. }


  90. void sleepNow() {
  91.   sleep_enable();//Enabling sleep mode
  92.   attachInterrupt(0, wakeUpNow, LOW);//attaching a interrupt to pin d2
  93.   set_sleep_mode(SLEEP_MODE_PWR_DOWN);//Setting the sleep mode, in our case full sleep

  95.   digitalWrite(ledPin, LOW); //turning LED off
  96.   time_t t;// creates temporary time variable
  97.   t = RTC.get(); //gets current time from RTC
  98.   Serial.println("Sleep  Time: " + String(hour(t)) + ":" + String(minute(t)) + ":" + String(second(t))); //prints time stamp on serial monitor
  99.   delay(1000); //wait one second to allow the LED to be turned off before going to sleep
  100.   sleep_cpu();//heres where the Arduino is actually put to sleep

  102.   Serial.println("just woke up!");//next line of code executed after the interrupt
  103.   digitalWrite(ledPin, HIGH); //turns the LED on
  104.   t = RTC.get();//get the new time from the RTC
  105.   Serial.println("WakeUp Time: " + String(hour(t)) + ":" + String(minute(t)) + ":" + String(second(t))); //Prints time stamp

  107.   getTempAndSoil(); //Run the TempAndSoil function
  108.   
  109. //Set New Alarm
  110.   int alarmTime = 0; //temporary variable to store the new alarm time in minutes
  111.   
  112. //the next few lines are to roll the alarm over when it gets near the next hour
  113. if (minute(t) <= (60-time_interval))
  114.   {
  115.     alarmTime = minute(t) + time_interval;
  116.   }
  117.   else
  118.   {
  119.     alarmTime = (minute(t) + time_interval) - 60;
  120.   }

  122.   RTC.setAlarm(ALM1_MATCH_MINUTES , 0, alarmTime, 0, 0); // set new alarm


  125. // The next few lines of code I use for troubleshooting.  This way I can make sure the clock is waking up at the correct time

  127. Serial.print("The next alarm will go off at: ");
  128.    
  129. //These lines are to print the correct hour that the next alarm will go off
  130. if ((minute(t) <= 60-time_interval) && (hour(t) <= 22))
  131.     {
  132.       Serial.print(hour(t));
  133.     }
  134.     else if ((minute(t) >= 60-time_interval) && (hour(t) <= 22))
  135.     {
  136.       Serial.print(hour(t) + 1);
  137.     }
  138.     else
  139.     {
  140.       Serial.print(0);
  141.     }
  142.   
  143.     Serial.print(":"); // print a colon symbol
  144.    
  145. //print the correct minute, including leading zero if less than 10
  146. if (alarmTime <= 9)
  147.     {
  148.       Serial.print("0");
  149.     }
  150.     Serial.println(alarmTime);

  152.   //Last thing we do is clear the alarm flag
  153.   RTC.alarm(ALARM_1);

  155. }

  157. void wakeUpNow()  //This is the code that happens when the interrupt is activated
  158. {
  159.   Serial.println("Interrrupt Fired");//Print message to serial monitor
  160.   sleep_disable();//Disable sleep mode
  161.   detachInterrupt(0); //Removes the interrupt from pin 2;
  162. }

  164. void getTempAndSoil()
  165. {
  166.   float  temperatureC = 0, tempF = 0;  //set up float variable to store Celsius and Fahrenheit temp

  168.   temperatureC = mpl115a2.getTemperature(); //get temperature from the sensor
  169.   tempF = (temperatureC * 1.8) + 32;  //convert the temperature from Celsius to Fahrenheit.
  170.   Serial.print("Temp (*F): "); Serial.print(tempF, 1); Serial.println(" *F");  //Print the temperature to the Serial Monitor
  171.   Serial.print("Soil Moisture = ");  
  172.   //get soil moisture value from the function below and print it
  173.   Serial.println(readSoil());
  174.   addWater();  // Run the add water function
  175. }

  177. int readSoil()
  178. {

  180.   digitalWrite(soilPower, HIGH);//turn the soil moisture sensor on
  181.   delay(10);//wait 10 milliseconds
  182.   moistureVal = analogRead(soilPin);//Read the value from sensor
  183.   digitalWrite(soilPower, LOW);//turn the soil moisture sensor off
  184.   return moistureVal;//send current moisture value
  185. }

  187. void addWater()
  188. {
  189.   if (moistureVal <= 100)  //If the soil moisture gets too low (The value will need to be set to accompany the soil that you are using)
  190.   {

  192. //This is where you could change the code to run a relay, or run a water pump to water your plant.  I just flashed a LED as an example to show that the plant would need to be watered.
  193.     for (int num = 0; num <= 10; num++)
  194.     {
  195.       digitalWrite(pumpLED, HIGH);
  196.       delay(1000);
  197.       digitalWrite(pumpLED, LOW);
  198.       delay(1000);
  199.       Serial.print("PUMP ON");
  200.       Serial.println(num);
  201.     }
  202.   }
  203. }
RTC 和传感器接线图




来源：digikey